Expansion automatique des alias dans Zsh

Vincent Bernat

Pour évi­ter les frappes su­per­flues, fish pro­pose des abré­via­tions de com­mandes qui se sub­sti­tuent après avoir ap­puyé sur la barre d’es­pace. Nous pou­vons ému­ler cette fonc­tion­na­lité avec Zsh:

# Définition de abbrev-alias pour la substitution automatique des alias
typeset -ga _vbe_abbrevations
abbrev-alias() {
    alias $1
    _vbe_abbrevations+=(${1%%\=*})
}
_vbe_zle-autoexpand() {
    local -a words; words=(${(z)LBUFFER})
    if (( ${​#_vbe_abbrevations[(r)${words[-1]}]} )); then
        zle _expand_alias
    fi
    zle magic-space
}
zle -N _vbe_zle-autoexpand
bindkey -M emacs " " _vbe_zle-autoexpand
bindkey -M isearch " " magic-space

# Corriger des typos
(( $+commands[git] )) && abbrev-alias gti=git
(( $+commands[grep] )) && abbrev-alias grpe=grep
(( $+commands[sudo] )) && abbrev-alias suod=sudo
(( $+commands[ssh] )) && abbrev-alias shs=ssh

# Économiser quelques touches
(( $+commands[git] )) && abbrev-alias gls="git ls-files"
(( $+commands[ip] )) && {
  abbrev-alias ip6='ip -6'
  abbrev-alias ipb='ip -brief'
}

# Options difficiles à se souvenir
(( $+commands[mtr] )) && abbrev-alias mtrr='mtr -wzbe'

Voici une dé­mons­tra­tion où git ls-files rem­place gls après avoir ap­puyé sur la barre d’espace:

Substitution automatique de gls par git ls-files

Je n’étends pas au­to­ma­ti­que­ment tous les alias. Je conti­nue à uti­li­ser des alias clas­siques pour mo­di­fier lé­gè­re­ment le com­por­te­ment d’une com­mande ou pour des abré­via­tions bien connues:

alias df='df -h'
alias du='du -h'
alias rm='rm -i'
alias mv='mv -i'
alias ll='ls -ltrhA'